package schema

#Client: {
	url: string
	tls_config?: {
		ca_file?:     string
		cert_file?:   string
		key_file?:    string
		server_name?: string
	}
}

#CommonScrapeConfig: {
	labels?: [string]: string
}

#JournalScrapeConfig: {
	#CommonScrapeConfig
	json: bool | *false
}

#KubernetesScrapeConfig: {
	#CommonScrapeConfig
	api_server?: string
	role:        "node" | "service" | "pod" | "endpoints" | "ingress"
}

#RelabelConfig: {
	source_labels?: [...string]
	separator?:    string
	target_label?: string
	regex?:        string
	modulus?:      int
	replacement?:  string
	action?:       "replace" | "keep" | "drop" | "hashmod" | "labelmap" |
		"labeldrop" | "labelkeep"
}

#ScrapeConfig: {
	job_name: string
	journal?: #JournalScrapeConfig
	static_configs?: [...#CommonScrapeConfig]
	kubernetes_sd_configs?: [...#KubernetesScrapeConfig]
	pipeline_stages?: [...#PipelineStage]
	relabel_configs?: [...#RelabelConfig]
}

#PromtailConfig: {
	server: {
		http_listen_port:      int | *9080
		grpc_listen_port:      int | *0
		enable_runtime_reload: bool | *true
	}

	clients: [...#Client]

	positions: {
		filename: string | *"/var/lib/promtail/positions"
	}

	scrape_configs: [...#ScrapeConfig]
}