if &compatible || v:version < 603 || exists("g:loaded_templates")
    finish
endif

let g:loaded_templates=1

fun! <SID>TemplateSetupPy()
    let l:pastebackup = &paste
    set nopaste

    if exists('$USER')
        let l:user = $USER
    elseif exists('$USERNAME')
        let l:user = $USERNAME
    else
        let l:user = 'unknown'
    endif

    if exists('g:my_email')
        let l:author_email = g:my_email
    else
        let l:author_email = l:user . '@' . hostname()
    endif
    if exists('g:my_name')
        let l:author = g:my_name
    else
        let l:author = l:user
    endif

    0 put ='from setuptools import find_packages, setup'
    put =''
    put ='setup('
    put ='    name='''','
    put ='    version='''','
    put ='    description='''','
    put ='    author=''' . l:author . ''','
    put ='    author_email=''' . l:author_email . ''','
    put ='    url='''','
    put ='    license='''','
    put ='    packages=find_packages(''src''),'
    put ='    package_dir={'''': ''src''},'
    put =')'
    $ del

    0
    /^\s\+name='/
    exec "normal 2f'"
    nohls

    if pastebackup != 0
        set paste
    endif
endfun

if !exists("g:templates_activate")
    let g:templates_activate = 1
endif

augroup Templates
    au!
    autocmd BufNewFile setup.py
        \ if g:templates_activate |
        \    call <SID>TemplateSetupPy() |
        \ endif
augroup END